谁能比vlookup更好用？很多同学看到标题就能猜出来：是lookup函数！这个2.2倍是怎么来的？看完本文即可揭晓。
Vlookup和 lookup长的太像了，以致于很多同学傻傻分不清。到底这两函数在使用上有什么不同？。今天兰色就让2个函数来一次全方位，多角度的终极PK，看看到底是哪个函数最好用。
评比规则：
能实现 1分，不能实现0分
运算速度快 1分，慢 0 分
易用性 好1分 ，不好 0分
PK1: 常规查找
【例1】如下图所示，根据姓名查找职位。
公式：
公式1 =VLOOKUP(B9,B1:E6,4,0)
公式2 =LOOKUP(B9,B2:B6,E2:E6) 结果错误
公式3 =LOOKUP(1,0/(B2:B6=B9),E2:E6)
简评：
vlookup在普通查找时，优势比较明显，公式2中lookup结果是错误的，显然易用性差，只能用公式3才能完成普通查找
本次得分：
VLOOKUP: 2分 Lookup：0分
PK2 反向查找
【例2】如下图所示，要求根据姓名查找工号。
公式
公式1：=VLOOKUP(B9,IF({1,0},B2:B6,A2:A6),2,0)
公式2：=LOOKUP(1,0/(B2:B6=B9),A2:A6)
简评：
VLOOKUP函数要借用IF函数才能完成，所以易用性弱了点，Lookup虽然用可以完成，但它属于区域数组运算，运算量大于vlookup。
本次得分：
VLOOKUP: 1分 Lookup：1分
总得分
VLOOKUP: 3分 Lookup：1分
PK3：多条件查找。
【例3】如下图所示要求，同时根据姓名和工号查找职位。
公式：
公式1：
{=VLOOKUP(B9&C9,IF({1,0},B2:B6&A2:A6,E2:E6),2,0)}
公式2：
=LOOKUP(1,1/(B2:B6=B9)*(A2:A6=C9),E2:E6)
简评：
VLOOKUP函数需要借助if函数完成查找，而且也要进行数组运算。而lookup函数在易用性上要强于Vlookup函数。
本次得分：
VLOOKUP: 0分 Lookup：1分
总得分
VLOOKUP: 3分 Lookup：2分
PK4:查找最后一条记录。
【例4】如下图所示，要求查找A产品的最后一次进价。
公式：
公式1：vlookup无法完成
公式2：
=LOOKUP(1,0/(B2:B9=A13),C2:C9)
简评：lookup本来就是从后向前查找，这正是它的优势，vlookup天生是从前向后查找。所以本次vlookup函数完败。
本次得分：
VLOOKUP: 0分 Lookup：3分
总得分
VLOOKUP: 3分 Lookup：5分
PK5: 区间查找
【例5】如下图所示,要求根据左表的提成比率表，在右表中根据销售额在G列查找适用的比率。
公式
公式1：
=VLOOKUP(F3,$B$3:$C$11,2)
公式2：
=LOOKUP(F3,B$3:B$11,C$3:C$11)
简评:
vlookup的最后一个参数为1或省略时，可以进行模糊查找。lookup也支持模糊查找。二者都需要B列按升序排列。所以本次PK二者打平。都不得分。
本次得分：
VLOOKUP: 0分 Lookup：0分
总得分
VLOOKUP: 3分 Lookup：5分
PK6:模糊查找之1
【例6】如下图所示，要求根据提供的城市从上表中查找该市名的第2列的值。
公式：
公式1：
=VLOOKUP(“*”&A7&”*”,A1:B4,2,0)
公式2：
=LOOKUP(9^9,FIND(A7,A2:A4),B2:B4)
简评：
二者都顺利的实现了模糊查找，但lookup函数需要借用FIND函数，而且还要需要进行数组运算，所以本轮lookup连失两分。
本次得分：
VLOOKUP: 2分 Lookup：0分
总得分
VLOOKUP: 5分 Lookup：5分
PK之7：模糊查找之2
【例7】如下图所示，要求根据地址从上表中查找所在城市的提成。
公式
公式1：VLOOKUP无法或很难完成。
公式2：
=lookup(9^9.find(A$3:A$6,A10),B$3:B$6)
简评：
VLOOKUP只能在第一个参数中添加通配符，所以本次查找就无能为力了，而LOOKUP则不受这个限制。本次lookup又一次完胜。
本次得分：
VLOOKUP: 0分 Lookup：3分
总得分
VLOOKUP: 5分 Lookup：8分
PK8：最后一个非空值查找。
【例8】如下图所示，要求查找最后一次还款日期。
公式：
公式1：VLOOKUP很难完成
公式2：
=LOOKUP(1,0/(B2:B13<>””),$A2:$A13)
简评：
查找最后一个非空数字，字符。是lookup函数的强项，vlookup函数只能望而生叹！本次vlookup又一次完败。
本次得分：
VLOOKUP: 0分 Lookup：3分
总得分
VLOOKUP: 5分 Lookup：11分
兰色说：最终lookup函数以11：5的优势在PK中获胜。这也再次证明lookup在查找能力上远胜于vlookup函数。不过兰色也需要提醒的是，日常工作中大部分都是普通查找，所以在一般查找时同学们还是要多用vlookup函数。
